You can convert HTML-based reports into PDF or FlashPaper output by wrapping the HTML in the cfdocument start and end tags, and specifying cfdocument attributes, as appropriate, to customize the following items:

• Page size

• Page orientation

• Margins

• Encryption (PDF only)

• User password and owner password (PDF only)

• Permissions (PDF only)

For complete information on these options, see the cfdocument tag discussion in the CFML Reference.

The following example displays a list of employees, using a cfoutput tag to loop through the query:

<cfdocument format="flashpaper"> 
<h1>Employee List</h1> 
<!--- Inline query used for example purposes only. ---> 
<cfquery name="EmpList" datasource="cfdocexamples"> 
    SELECT FirstName, LastName, Salary, Contract 
    FROM Employee 
</cfquery> 
<cfoutput query="EmpList"> 
#EmpList.FirstName#, #EmpList.LastName#, #LSCurrencyFormat(EmpList.Salary)#, 
    #EmpList.Contract#<br> 
</cfoutput> 
</cfdocument>

You can use the cfdocument and cfdocumentsection tags to fine-tune your printable output, as follows:

• cfdocumentitem: Creates page breaks, headers, or footers.

• cfdocumentsection: Divides output into sections, optionally specifying custom margins. Within a section, use the cfdocumentitem tag to specify unique headers and footers for each section. Each document section starts on a new page.

When you use the cfdocument tag, ColdFusion creates a scope named cfdocument. This scope contains the following variables:

currentpagenumber

Displays the current page number.

totalpagecount

Displays the total page count.

currentsectionpagenumber

Displays the current section number.

totalsectionpagecount

Displays the total number of sections.

You typically use these variables in a header or footer to display the current page number and total number or pages, as the following example shows:

<cfdocumentitem type= "footer> #cfdocument.currentpagenumber# of 
    #cfdocument.totalpagecount#</cfdocumentitem>

You can use the cfdocumentbookmark attribute to create bookmarks for each section within a PDF document, as the following example shows:

<cfdocument format="PDF" bookmark="yes"> 
    <cfdocumentitem type="header"> 
    <font size="-1" align="center"><i>Building Better Applications</i></font> 
    </cfdocumentitem> 
    <cfdocumentitem type="footer"> 
    <font size="-1"><i>Page <cfoutput>#cfdocument.currentpagenumber# of 
        #cfdocument.totalpagecount#</cfoutput></i></font> 
    </cfdocumentitem> 
    <cfdocumentsection name="Introduction"> 
        <h3>Introduction</h3> 
        <p>The introduction goes here.</p> 
    </cfdocumentsection> 
    <cfdocumentsection name="Chapter 1"> 
        <h3>Chapter 1: Getting Started</h3> 
        <p>Chapter 1 goes here.</p> 
    </cfdocumentsection> 
    <cfdocumentsection name="Chapter 2"> 
        <h3>Chapter 2: Building Applications</h3> 
        <p>Chapter 2 goes here.</p> 
    </cfdocumentsection> 
    <cfdocumentsection name="Conclusion"> 
        <h3>Conclusion</h3> 
        <p>The conclusion goes here.</p> 
    </cfdocumentsection> 
</cfdocument>

The bookmarks appear in the bookmarks panel of the PDF document.

You can use the cfhttp tag in combination with the cfdocument tag to display entire web pages in PDF or FlashPaper output format, as the following example shows:

<!--- You can pass a URL in the URL string ---> 
<cfparam name="url.target_url" default="http://www.boston.com"> 
<cfoutput> 
<cfhttp url="#url.target_url#" resolveurl="yes"> 
 
<cfdocument format="FlashPaper"> 
<cfdocumentitem type="header"> 
    <cfoutput>#url.target_url#</cfoutput> 
</cfdocumentitem> 
<cfdocumentitem type="footer"> 
    <cfoutput>#cfdocument.currentpagenumber# / #cfdocument.totalpagecount#</cfoutput> 
</cfdocumentitem> 
<!--- Display the page ---> 
#cfhttp.filecontent# 
</cfdocument> 
</cfoutput>

The cfdocument tag supports the Acrobat security options, as the following table shows:

Additionally, the cfdocument tag supports the following Acrobat security permissions through the permissions attribute. Specify one or more of the following values; separate multiple permissions with a comma:

The following example creates a PDF document that allows copying only:

<cfdocument format="PDF" encryption="40-bit" 
    ownerpassword="us3rpa$$w0rd" userpassword="us3rpa$$w0rd" 
    permissions="AllowCopy" > 
<h1>Employee List</h1> 
<cfquery name="EmpList" datasource="cfdocexamples"> 
    SELECT FirstName, LastName, Salary 
    FROM Employee 
</cfquery> 
<cfoutput query="EmpList"> 
    #EmpList.FirstName#, #EmpList.LastName#, #LSCurrencyFormat(EmpList.Salary)#<br> 
</cfoutput> 
</cfdocument>

You can use the cfdocument filename attribute to save the generated PDF or SWF content to a file, as the following example shows:

<!--- The compasstravel database is part of the Getting Started 
    tutorial application, found under the cfdocs directory. ---> 
<cfquery datasource="compasstravel" name="compasstrips"> 
SELECT tripName, tripDescription, tripLocation, price 
FROM trips 
ORDER BY price 
</cfquery> 
<cfdocument format="pdf" 
        filename="#GetDirectoryFromPath(GetTemplatePath())#/compasstrips.pdf" 
        overwrite="yes"> 
    <cfdocumentsection>  
        <h1 align="center">Compass Travel</h1> 
        <h2 align="center">Destination Guide</h2> 
        <p align="center"><img src="cfdocs/getting_started/photos/somewhere.jpg"></p> 
    </cfdocumentsection>  
    <cfdocumentsection>  
        <cfdocumentitem type="header"> 
            <font size="-3"> <i>Compass Travel Trip Descriptions</i></font> 
        </cfdocumentitem>  
        <cfdocumentitem type="footer">  
            <font size="-3">  
                <cfoutput>Page #cfdocument.currentpagenumber#</cfoutput> 
            </font>  
        </cfdocumentitem>  
        <cfoutput query="compasstrips">  
            <hr> 
            <h2>#tripName#</h2> 
            <p><b>#tripLocation#</b></p> 
            <p>Price: #DollarFormat(price)#</p> 
            <p>#tripDescription#</p> 
        </cfoutput>  
    </cfdocumentsection>  
</cfdocument>